【www.xxxnonstop.com--股票公式】

通达信涨停密码指标公式

{———— 基础部分 ————}
0,POINTDOT,COLOR808080;
12,POINTDOT,COLOR808080;
绿低量:=10;
蓝低量:=50;
灰低量:=100;
量:=VOL;
换手:= VOL*10000/FINANCE(7),NODRAW;
全换手周期:= SUMBARS(V,CAPITAL),NODRAW;{求完全换手到现在的周期数}
量比:= V/REF(MA(V,5),1),NODRAW;
几倍:= V/REF(V,1),NODRAW;
倍数:=1.9;
倍量:= VOL>=REF(V,1)*倍数 AND (IF(C<O,C>REF(C,1),1)),NODRAW;
倍缩:= REF(V,1)>=VOL*倍数,NODRAW;
平量:= RANGE(V/REF(V,1),0.97,1.03) AND BARSCOUNT(V)>=2,NODRAW;
低量10:= VOL=LLV(VOL,绿低量) AND BARSCOUNT(V)>=绿低量,NODRAW;
低量50:= VOL=LLV(VOL,蓝低量) AND BARSCOUNT(V)>=蓝低量,NODRAW;
地量:=VOL=LLV(VOL,灰低量) AND BARSCOUNT(V)>=灰低量,NODRAW;
真阳或假阴:=C>O OR C>REF(C,1);
收阳:= REF(真阳或假阴,3);
倍量1:=REF(倍量,3);
高量:=REF(V,3)>=HHV(V,7);
三日不破:= LLV(C,3)>=REF(L,3);
价升:=COUNT(C>=REF(C,1),3)=3;{收盘价逐升}
量缩:=COUNT(V<=REF(V,1),3)=3;
连阳:= COUNT(真阳或假阴,3)=3;
倍量将军柱:= 倍量1 AND 三日不破 AND 收阳;
高量将军柱:= 高量 AND 三日不破 AND 收阳;
V100:= V<=LLV(V,100)*1.2 AND V>0 AND BARSCOUNT(V)>=100;
NOTEXT_将军柱: REFX(倍量将军柱 OR 高量将军柱,3),NODRAW;
NOTEXT_黄金柱: NOTEXT_将军柱 AND REFX(价升,3) AND REFX(量缩,3) AND REFX(连阳,3),NODRAW;{标准黄金柱}
NOTEXT_元帅柱:REFX(NOTEXT_将军柱 OR NOTEXT_黄金柱,1) AND H<REFX(L,1),NODRAW;
百日地量群:COUNT(V100,5)>=3,COLORLIGRAY,NODRAW;
STICKLINE(百日地量群,1,1.5,2,0),COLORLIGRAY;
{———— 涨跌停 ————}
RC1:=REF(C,1);
CS:=IF(C>=1,10000,100000);
C涨停10:=1.10*RC1-49/CS;{考虑到4舍5入}
C涨停5 :=1.05*RC1-49/CS;
C跌停10:=0.90*RC1+51/CS;
C跌停5 :=0.95*RC1+51/CS;
ST:=NAMELIKE(‘S’) OR NAMELIKE(‘*S’);
盘中涨停:=IF(ST, H>=C涨停5, H>=C涨停10);
盘中跌停:=IF(ST, L<=C跌停5, L<=C跌停10);
NOTEXT_跌停: IF(ST, C<=C跌停5, C<=C跌停10),COLORLIGRAY,NODRAW;
NOTEXT_涨停: IF(ST, C>=C涨停5, C>=C涨停10),COLORLIGRAY,NODRAW;
{———— 大阴大阳 ————}
NOTEXT_大阳线:C>O AND (C>=C涨停5 OR C>(1.05*O-51/CS) ) OR (C>1000 AND C>RC1*1.024),COLORLIGRAY,NODRAW;
NOTEXT_大阴线:C<O AND (C<=C跌停5 OR C<(0.95*O+49/CS) ) OR (C>1000 AND C<RC1*0.976),COLORLIGRAY,NODRAW;
{———— 过左峰(含倍量、缩量、零号） ————}
TY1:=C;
HD1:=FILTER(BACKSET(FILTER(REF(TY1,10)=HHV(TY1,2*10+1),10),10+1),10);
LD1:=FILTER(BACKSET(FILTER(REF(TY1,10)=LLV(TY1,2*10+1),10),10+1),10);
A5:=REF(C,BARSLAST(HD1));
T9:=BARSLAST(HD1)<BARSLAST(LD1) AND NOT(HD1) ;
波浪顶:=IF(T9,A5,A5);
过左峰:CROSS(C,波浪顶),COLORLIGRAY,NODRAW;
STICKLINE(过左峰,2,2.5,2,0),COLORLIGRAY;
{———— 倍量伸缩 ————}
A8A1:=VOL/REF(VOL,1)>1.9 AND C/REF(C,1)>1.03;
B8A1:=VOL/REF(VOL,1)<0.6 AND REF(C,1)>REF(C,2) AND C/REF(C,1)>0.99 AND C/REF(C,1)<1.01;
ZF9A:=(C-REF(C,1))/REF(C,1)*100;
NOST9A:=EXIST(ZF9A>5.2,100) OR EXIST(ZF9A<-5.2,100);
K109A:=SLOPE(CLOSE,10)>0.02;
倍量伸缩:COUNT(A8A1,5) AND COUNT(B8A1,5) AND NOST9A AND K109A AND C>REF(C,1),COLORLIGRAY,NODRAW;
STICKLINE(倍量伸缩,3,3.5,2,0),COLORLIGRAY;
{———— 长阴短柱 ————}
长阴短柱:C/REF(C,1)<=0.96 AND V<HHV(V,30)/1.9,COLORLIGRAY,NODRAW;
STICKLINE(长阴短柱,4,4.5,2,0),COLORLIGRAY;
{———— 双剑 ————}
长上影:=(HIGH-MAX(CLOSE,OPEN))/(HIGH-LOW)>0.667;
长腿A:= (MIN(O,C)-L)/(H-L)>0.3 AND (MIN(O,C)-L)/C>=0.03;
双剑:=REF(长上影,1) AND 长腿A AND REF(MIN(C,O),1)>=MAX(C,O),COLORLIGRAY,NODRAW;
双剑霸:REF(双剑,1) AND C>REF(C,1),COLORLIGRAY,NODRAW;
STICKLINE(双剑霸,5,5.5,2,0),COLORLIGRAY;
{———— 假阳真阴 ————};
均价:=AMOUNT/VOL/100;
假阳真阴:=C>O AND REF(C,1)>均价 AND C>均价,NODRAW;
{———— 假阴真阳 ————};
假阴真阳:O>C AND C<均价 AND 均价>REF(C,1),COLORLIGRAY,NODRAW;
STICKLINE(假阴真阳,6,6.5,2,0),COLORLIGRAY;
{———— 极阴次阳 ————};
ZF:=(C-REF(C,1))/REF(C,1)*100;
极阴:=ZF<= -3;
次阳:=C > O AND C > REF((O+C)/2,1);
极阴次阳:极阴 AND 次阳,COLORLIGRAY,NODRAW;
STICKLINE(极阴次阳,7,7.5,2,0),COLORLIGRAY;
{———— 三元连动 ————};
ZTB1:=EVERY(C>REF(C,1) ,3);
ZTB2:=EVERY(O>REF(C,1),2);
三连元:ZTB1 AND ZTB2,COLORLIGRAY,NODRAW;
STICKLINE(三连元,8,8.5,2,0),COLORLIGRAY;
{———— 悬阴31 ————}
{———— T4变异 ————}
T3:=V>REF(V,1) AND REF(V,1)>REF(V,2) AND C=HHV(C,3);
T4变异:REF(T3,1) AND C>REF(C,1),COLORLIGRAY,NODRAW;
STICKLINE(T4变异,9,9.5,2,0),COLORLIGRAY;
{———— 现场直憋 ————}
DD1:=REF(C,10)/REF(C,9)>=1.05 AND REF(C,9)<REF(O,9);
DD2:=REF(C,10)/REF(C,8)>=1.05 AND REF(C,9)<REF(O,9) AND REF(C,8)<REF(O,8) AND REF(C,9)>REF(C,8);
DD:=DD1 OR DD2;
ZB1:=HHV(H,8)/REF(H,9)<1.04 AND LLV(L,8)/REF(L,9)>0.96;
ZB2:=HHV(H,8)/REF(H,9)<1.04 AND LLV(L,7)/REF(L,8)>0.96;
ZB:=ZB1 OR ZB2;
现场直憋:DD AND ZB,COLORLIGRAY,NODRAW;
STICKLINE(现场直憋,10,10.5,2,0),COLORLIGRAY;
{———— 牛股三绝 ————}
HH:=HHV(VOL,10);
T:=BARSLAST(HH=VOL)=1;
跳空:=HIGH<(REF(LOW,1)-0.001) || LOW>(REF(HIGH,1)+0.001);
倍量不穿:=REF(倍量,1) AND O>=REF(C,1) AND C/REF(C,1)>=1.03,NODRAW;
高量不破:=O>=REF(MAX(O,C),T) AND C>REF(MAX(O,C),T),NODRAW;
跳空不补:=跳空 AND C>O AND C>REF(C,1),NODRAW;
牛股三绝:倍量不穿 OR 高量不破 OR 跳空不补,COLORLIGRAY,NODRAW;
STICKLINE(牛股三绝,11,11.5,2,0),COLORLIGRAY;
{———————— 统计 ————————}
基因统计:百日地量群+过左峰+倍量伸缩+长阴短柱+双剑+假阴真阳+极阴次阳+三连元+T4变异+现场直憋+牛股三绝,COLORLIGRAY,NODRAW;
位置:=15;
DRAWNUMBER(百日地量群,位置,基因统计),COLORFFFFFF;
DRAWNUMBER(过左峰,位置,基因统计),COLORFFFFFF;
DRAWNUMBER(倍量伸缩,位置,基因统计),COLORFFFFFF;
DRAWNUMBER(长阴短柱,位置,基因统计),COLORFFFFFF;
DRAWNUMBER(双剑,位置,基因统计),COLORFFFFFF;
DRAWNUMBER(假阴真阳,位置,基因统计),COLORFFFFFF;
DRAWNUMBER(极阴次阳,位置,基因统计),COLORFFFFFF;
DRAWNUMBER(三连元,位置,基因统计),COLORFFFFFF;
DRAWNUMBER(T4变异,位置,基因统计),COLORFFFFFF;
DRAWNUMBER(现场直憋,位置,基因统计),COLORFFFFFF;
DRAWNUMBER(牛股三绝,位置,基因统计),COLORFFFFFF;

本文来源：http://www.xxxnonstop.com/gupiaozhuanti/15115.html